كيف أحصل على رقم ال MAC Address ?

يا أخوان معقول لا يوجد أحد يعرف؟؟؟؟

عبرونا....

**** الكود منقول ****

خاص بفيجوال بيسك 6

يمكنك ايضاً الاستعانه ببرنامج all api الكتاب و البرنامج على هذا الرابط

/index.php?showtopic=39269

Option Explicit

Private Const NCBASTAT As Long = &H33
Private Const NCBNAMSZ As Long = 16
Private Const HEAP_ZERO_MEMORY As Long = &H8
Private Const HEAP_GENERATE_EXCEPTIONS As Long = &H4
Private Const NCBRESET As Long = &H32

Private Type NET_CONTROL_BLOCK  'NCB
   ncb_command    As Byte
   ncb_retcode    As Byte
   ncb_lsn        As Byte
   ncb_num        As Byte
   ncb_buffer     As Long
   ncb_length     As Integer
   ncb_callname   As String * NCBNAMSZ
   ncb_name       As String * NCBNAMSZ
   ncb_rto        As Byte
   ncb_sto        As Byte
   ncb_post       As Long
   ncb_lana_num   As Byte
   ncb_cmd_cplt   As Byte
   ncb_reserve(9) As Byte 'Reserved, must be 0
   ncb_event      As Long
End Type

Private Type ADAPTER_STATUS
   adapter_address(5) As Byte
   rev_major         As Byte
   reserved0         As Byte
   adapter_type      As Byte
   rev_minor         As Byte
   duration          As Integer
   frmr_recv         As Integer
   frmr_xmit         As Integer
   iframe_recv_err   As Integer
   xmit_aborts       As Integer
   xmit_success      As Long
   recv_success      As Long
   iframe_xmit_err   As Integer
   recv_buff_unavail As Integer
   t1_timeouts       As Integer
   ti_timeouts       As Integer
   Reserved1         As Long
   free_ncbs         As Integer
   max_cfg_ncbs      As Integer
   max_ncbs          As Integer
   xmit_buf_unavail  As Integer
   max_dgram_size    As Integer
   pending_sess      As Integer
   max_cfg_sess      As Integer
   max_sess          As Integer
   max_sess_pkt_size As Integer
   name_count        As Integer
End Type
   
Private Type NAME_BUFFER
   name        As String * NCBNAMSZ
   name_num    As Integer
   name_flags  As Integer
End Type

Private Type ASTAT
   adapt          As ADAPTER_STATUS
   NameBuff(30)   As NAME_BUFFER
End Type

Private Declare Function Netbios Lib "netapi32" (pncb As NET_CONTROL_BLOCK) As Byte
     
Private Declare Sub CopyMemory Lib "kernel32" Alias "RtlMoveMemory" (hpvDest As _
    Any, ByVal hpvSource As Long, ByVal cbCopy As Long)
     
Private Declare Function GetProcessHeap Lib "kernel32" () As Long

Private Declare Function HeapAlloc Lib "kernel32" (ByVal hHeap As Long, ByVal _
    dwFlags As Long, ByVal dwBytes As Long) As Long
     
Private Declare Function HeapFree Lib "kernel32" (ByVal hHeap As Long, ByVal dwFlags _
    As Long, lpMem As Any) As Long

Public Function GetMACAddress() As String
Dim x As Integer
Dim tmp As String
Dim pASTAT As Long
Dim NCB As NET_CONTROL_BLOCK
Dim AST As ASTAT

NCB.ncb_command = NCBRESET
Call Netbios(NCB)

NCB.ncb_callname = "*               "
NCB.ncb_command = NCBASTAT

NCB.ncb_lana_num = 0
NCB.ncb_length = Len(AST)

pASTAT = HeapAlloc(GetProcessHeap(), HEAP_GENERATE_EXCEPTIONS Or HEAP_ZERO_MEMORY, NCB.ncb_length)
         
If pASTAT = 0 Then
   Debug.Print "memory allocation failed!"
   Exit Function
End If

NCB.ncb_buffer = pASTAT
Call Netbios(NCB)

CopyMemory AST, NCB.ncb_buffer, Len(AST)

For x = 0 To 5
    tmp = tmp & Right$("00" & Hex(AST.adapt.adapter_address(x)), 2) & "-"
Next x
                 
tmp = Left(tmp, Len(tmp) - 1)
                 
HeapFree GetProcessHeap(), 0, pASTAT

GetMACAddress = tmp

End Function

ايضاً خاص بفيجوال بيسك دوت نيت

'To get a www address 
Dim i As Integer 
Dim ipE As IPHostEntry = Dns.GetHostByName("www.ibm.com") 
Dim IpA() As IPAddress = ipE.AddressList 
For i = 0 To IpA.GetUpperBound(0) 
    Console.Write("IP Address {0}: {1} ", i, IpA(i).ToString) 
Next 

'To get local address 
Dim sHostName As String 
Dim i As Integer 
sHostName = Dns.GetHostName() 
Dim ipE As IPHostEntry = Dns.GetHostByName(sHostName) 
Dim IpA() As IPAddress = ipE.AddressList 
For i = 0 To IpA.GetUpperBound(0) 
    Console.Write("IP Address {0}: {1} ", i, IpA(i).ToString) 
Next

لاتنسى هنا ان تعمل imports لل :

System.Net

System.Net.Sockets

ارجو ان تعذرنى على كسلى للاسف لايوجد لدى دوت نيت لاضع لك الكود فى مشروع او حتى لدى وقت للتعليق على الكود

أخ طارق... السلام عليكم ...

أشكرك كثيراً لإجابتك... فقد فرّجت عني... فرّج الله عنك