فتح صفحه ويب

نعم باستخدام الاداة Microsoft Internet Controls

قم باضافتها على النافذة

راح يكون اسمها WebBrowser1

لفتح اي موقع اكتب

WebBrowser1.Navigate "http://al-dheya.net/sb"

شكرا لك اخي عبدالكريم وان شاء الله نستفيد منك اكثر ..........................

مشكور علي المساعدة ولكن اريد أن اضع في فورم عن البرنامج رابط لبريد الكتروني وموقع ويب كيف يتم ذلك؟

ممكن نضع عنوان الموقع في الكود ويفتحة على الإكس بلور

'Add 1 CommandButton to your form (named Command1),
'To launch URL with default browser press the button.
'Insert the following code to your form:


Private Sub Command1_Click()
'Replace http://www.yahoo.com with the URL you want to launch.
'You can replace 'vbHide' with following settings, according to in which state
'you want to open the browser :
'vbHide; vbMaximizedFocus; vbMinimizedFocus;vbMinimizedNoFocus;
'vbNormalFocus; vbNormalNoFocus
RetVal = SHELL("Start.exe http://www.yahoo.com", vbHide)
End Sub

Start.exe على ما أذكر فى Win9X بس , أستخدم يا أخى كود الـ ShellExecute أعمل بحث بالكلمة دى و هتلاقى نتائج كتير

أخي العزيز مشكور علي المساعدة ولكني جربت ها الكود ولكن لا يعمل أنا اريد وضع رابط البريد الالكتروني او صفحة الويب في هيئة لينكيتم الضغط عليه فيفتح صفحة الويب وكأنه Lable

'أضف أداتي عنوان ثم أضف الكود التالي في النموذج
Private Declare Function ShellExecute Lib "shell32.dll" Alias _
	"ShellExecuteA" (ByVal hwnd As Long, ByVal lpOperation As String, _
	ByVal lpFile As String, ByVal lpParameters As String, _
	ByVal lpDirectory As String, ByVal nShowCmd As Long) As Long

Private Sub Label1_Click()
	Dim ret&
	ret = ShellExecute(Me.hwnd, "Open", _
		"http://www.yahoo.com", _
		"", "", 1)
End Sub

Private Sub Label1_MouseDown(Button As Integer, Shift As Integer, _
	X As Single, Y As Single)
	Label1.ForeColor = vbRed
End Sub

Private Sub Label1_MouseUp(Button As Integer, Shift As Integer, _
	X As Single, Y As Single)
	Label1.ForeColor = vbBlue
End Sub

Private Sub Label2_MouseDown(Button As Integer, Shift As Integer, _
	X As Single, Y As Single)
	Label2.ForeColor = vbRed
End Sub

Private Sub Label2_MouseUp(Button As Integer, Shift As Integer, _
	X As Single, Y As Single)
	Label2.ForeColor = vbBlue
End Sub

Private Sub Label2_Click()
	Dim ret&
	ret = ShellExecute(Me.hwnd, "Open", _
		"mailto:abdulkareem@web.com?Subject=What's up?", _
		"", "", 1)
End Sub

Private Sub Form_Load()
	With Label1
		.AutoSize = True
		.ForeColor = vbBlue
		.Font.Italic = True
		.Font.Underline = True
		.Caption = "http://www.al-dheya.net"
	End With
	With Label2
		.AutoSize = True
		.ForeColor = vbBlue
		.Font.Italic = True
		.Font.Underline = True
		.Caption = "abdulkareem@mailserver.com"
	End With
End Sub