عمل نموذج full screen

كتب الأستا\ فيصل الحربي ذات يوم ما يلي:

السلام عليكم ورحمة الله وبركاته

إليكم طريقة إخفاء شاشة الأكسس نهائيا بعد فتح النموذج المطلوب

1- انشئ قاعدة بيانات جديده

2- انسخ الكود التالي ثم الصقه في وحده نمطيه جديدة وسمها أي اسم ترغب به

الكود

===============================================

 
Option Compare Database 
Option Explicit 

Global Const SW_HIDE = 0 
Global Const SW_SHOWNORMAL = 1 
Global Const SW_SHOWMINIMIZED = 2 
Global Const SW_SHOWMAXIMIZED = 3 

Private Declare Function apiShowWindow Lib "user32" _ 
Alias "ShowWindow" (ByVal hwnd As Long, _ 
ByVal nCmdShow As Long) As Long 

Function fSetAccessWindow(nCmdShow As Long) 
'Usage Examples 
'Maximize window: 
' ?fSetAccessWindow(SW_SHOWMAXIMIZED) 
'Minimize window: 
' ?fSetAccessWindow(SW_SHOWMINIMIZED) 
'Hide window: 
' ?fSetAccessWindow(SW_HIDE) 
'Normal window: 
' ?fSetAccessWindow(SW_SHOWNORMAL) 
' 
Dim loX As Long 
Dim loForm As Form 
On Error Resume Next 
Set loForm = Screen.ActiveForm 
If Err <> 0 Then 'no Activeform 
If nCmdShow = SW_HIDE Then 
'MsgBox "Cannot hide Access unless " _ 
& "a form is on screen" 
Else 
loX = apiShowWindow(hWndAccessApp, nCmdShow) 
Err.Clear 
End If 
Else 
If nCmdShow = SW_SHOWMINIMIZED And loForm.Modal = True Then 
'MsgBox "Cannot minimize Access with " _ 
& (loForm.Caption + " ") _ 
& "form on screen" 
ElseIf nCmdShow = SW_HIDE And loForm.PopUp <> True Then 
'MsgBox "Cannot hide Access with " _ 
& (loForm.Caption + " ") _ 
& "form on screen" 
Else 
loX = apiShowWindow(hWndAccessApp, nCmdShow) 
End If 
End If 
fSetAccessWindow = (loX <> 0) 
End Function

===============================================

3- انشئ نموذج جديد وسمه اي اسم ترغب به

4- غير خصائص النموذج الى

pop up=yes

modal=yes

5- ضع زر امر لإغلاق النموذج مع الأكسس

6- ضع في حدث عند الفتح الكود التالي

الكود

==============================================

 fSetAccessWindow (SW_SHOWMINIMIZED) 
fSetAccessWindow (SW_HIDE)

==============================================

7- من قائمة أدوات اختر بدء التشغيل ثم حدد النموذج لكي يفتح في بدء التشغيل

8- إحفظ عملك ثم قم بإنهاء القاعدة .

9- شغل القاعدة وسوف ترى ان خلفية الأكسس مختفيه تماما ما عدا النموذج الذي اخترته من قائمة بدء التشغيل .

10 -دعواتكم لنا بالتوفيق

مرفق مثال على الطريقة

تحياتي (f)

========

بالنسبة للمثال سوف ألحقة لاحقا بعد البحث عنه

الحمد لله وجدت المثال

hideaccesswindow.zip

جزاك الله خيرا يا أخي فهذا ما كنت في حاجة إلية تماما

أرجوا أن يكون بيننا تواصل عبر المسينجر

ashraf997@hotmail.com

أو

علي البريد الالكتروني

ashrafsa1972@arabia.com

وجزاك الله خيراَ