الفريق العربي للبرمجةأرشيف المنتديات · 2000 – 2023
نسخة أرشيفية للقراءة فقط — التسجيل والمشاركة مغلقان، والمحتوى محفوظ كما كان.

التحويل من (ADO) إلى (DOA)

مغلق
بدأه booknet في 10 نوفمبر 2004 · 3 رد · 538 مشاهدة · في لغة Ms Visual Basic 6 وما قبلها من إصدارات
مشاركة: واتساب X فيسبوك تيليجرام
#1 صاحب الموضوع

هل يمكن تحويل هذا الكود من (ADO) إلى (DOA)

Dim Con1 As Connection
Dim Rs As Recordset
Sub OpenMyData()
    Set Con1 = New Connection
    Con1.CursorLocation = adUseClient
    Con1.Open "PROVIDER=Microsoft.Jet.OLEDB.4.0;Data Source=" & App.Path & "\db1.mdb;"
End Sub
Sub ReadData()
    Set Rs = New Recordset
    Rs.Open "SELECT AccountTree.AccountNo, AccountTree.AccountName, AccountTree.SubAccountKey, AccountTree.AccountKey From AccountTree ORDER BY AccountTree.AccountNo;", Con1, adOpenStatic, adLockOptimistic
    Rs.MoveFirst
       If TreeView1.Nodes.Count > 0 Then TreeView1.Nodes.Clear
    TreeView1.Nodes.Add , , "A", "دليل الحسابات"
       While Rs.EOF <> True
        TreeView1.Nodes.Add CStr(Rs!SubAccountKey), 4, CStr(Rs!AccountKey), CStr(Rs!AccountName)
        Rs.MoveNext
    Wend
End Sub

Private Sub Form_Load()
    OpenMyData
    ReadData
End Sub
#2

السلام عليكم

اولا استخدم مكتبة

Microsoft DAO 3.6 Object Library

هذا الكود بعد التعديل

Dim db As Database
Dim Rs As Recordset

Sub OpenMyData()
Set db = DBEngine.Workspaces(0).OpenDatabase(App.Path & "\db1.mdb")
End Sub

Sub ReadData()
   Set Rs = db.OpenRecordset("SELECT AccountTree.AccountNo, AccountTree.AccountName, AccountTree.SubAccountKey, AccountTree.AccountKey From AccountTree ORDER BY AccountTree.AccountNo")
   Rs.MoveFirst
      If TreeView1.Nodes.Count > 0 Then TreeView1.Nodes.Clear
   TreeView1.Nodes.Add , , "A", "دليل الحسابات"
      While Rs.EOF <> True
       TreeView1.Nodes.Add CStr(Rs!SubAccountKey), 4, CStr(Rs!AccountKey), CStr(Rs!AccountName)
       Rs.MoveNext
   Wend
End Sub

Private Sub Form_Load()
   OpenMyData
   ReadData
End Sub
#3

شكرا لك أخي العزيز Hatam

يبقى شيئ واحد وهو عند النقر على فرع الشجرة يظهر محتوى "Kotob" من الداتا "db1.mdb" في التكست بوكس

لقد كتبت هذا الكود ولم ينفع، المثال مرفق

Private Sub TreeView1_NodeClick(ByVal Node As MSComctlLib.Node)
Set Rs = db.OpenRecordset("SELECT AccountTree.AccountNo, AccountTree.AccountName, AccountTree.SubAccountKey, AccountTree.Kotob, AccountTree.AccountKey From AccountTree ORDER BY AccountTree.AccountNo")
Text1.Text = Rs!Kotob
End Sub

شكرا

treeview.zip

تم تعديل هذه المشاركة بواسطة booknet في 11 نوفمبر 2004 في 15:15

#4

السلام عليكم

جرب هذا الكود وإن شاء الله يكون هو المطلوب .

Private Sub TreeView1_NodeClick(ByVal Node As MSComctlLib.Node)
If Node <> "دليل الحسابات" Then
    Set Rs = db.OpenRecordset("SELECT AccountTree.Kotob From AccountTree where AccountTree.AccountName='" & Node & "'")
    Text1.Text = Rs!Kotob
End If
End Sub

هذا الموضوع مغلق.

مواضيع مشابهة